haskell-jp / code-review #3

astFix :: forall t (i :: AstIx). IxFunctor t => AstIxProxy i -> AstIxFixParser t i
astFix proxy d e p t = case proxy of
    DeclProxy -> d'
    ExprProxy -> e'
    PattProxy -> p'
    TypeProxy -> t'
  where
    astFix' :: (forall f. AstIxParser t f j) -> Parser (IxFix t j)
    astFix' f = In <$> f d' e' p' t'

    d' = astFix' d
    e' = astFix' e
    p' = astFix' p
    t' = astFix' t
{-# INLINEABLE astFix #-}

located :: forall f (i :: AstIx). AstIxParser AstF f i -> AstIxParser (IxAnnF Location AstF) f i
located f d e p t = IxAnnF <$> withLocation (f d e p t)
{-# INLINE located #-}

astParser :: AstIxProxy i -> Parser (IxAnn Location AstF i)
astParser proxy = astFix proxy
  (located declAstF) (located exprAstF) (located pattAstF) (located typeAstF)

declAst :: Parser (IxAnn Location AstF AstDecl)
declAst = astParser DeclProxy
{-# INLINEABLE declAst #-}

exprAst :: Parser (IxAnn Location AstF AstExpr)
exprAst = astParser ExprProxy
{-# INLINEABLE exprAst #-}

pattAst :: Parser (IxAnn Location AstF AstPatt)
pattAst = astParser PattProxy
{-# INLINEABLE pattAst #-}

typeAst :: Parser (IxAnn Location AstF AstType)
typeAst = astParser TypeProxy
{-# INLINEABLE typeAst #-}